From 34fd83a7dcea57fde168183d81781269bd2ca4f9 Mon Sep 17 00:00:00 2001
From: Stephane Bailliez <sbailliez@apache.org>
Date: Wed, 4 Dec 2002 00:53:02 +0000
Subject: [PATCH] Modest contribution to help Stefan if he wants to test for
 Forrest.

I doubt this is complete and there should probably be some tweaks
to do as it will remove some br formatting (and I did not test yet under
Forrest, only from the top of my head). Not perfect, but this should
somewhat ease the conversion by doing most of the borring work.

cya


git-svn-id: https://svn.apache.org/repos/asf/ant/core/trunk@273608 13f79535-47bb-0310-9956-ffa450edef68
---
 proposal/ant-site/forrest/anakia2forrest.xsl | 134 +++++++++++++++++++
 proposal/ant-site/forrest/build.xml          |  18 +++
 proposal/ant-site/forrest/project2book.xsl   |  36 +++++
 3 files changed, 188 insertions(+)
 create mode 100644 proposal/ant-site/forrest/anakia2forrest.xsl
 create mode 100644 proposal/ant-site/forrest/build.xml
 create mode 100644 proposal/ant-site/forrest/project2book.xsl

diff --git a/proposal/ant-site/forrest/anakia2forrest.xsl b/proposal/ant-site/forrest/anakia2forrest.xsl
new file mode 100644
index 000000000..f24cead91
--- /dev/null
+++ b/proposal/ant-site/forrest/anakia2forrest.xsl
@@ -0,0 +1,134 @@
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
+<!--
+
+  A little bit of automated transformation to help conversion
+  from Anakia to Forrest/Cocoon docs.
+  
+  This is purely experimental, it hem...should work, well mostly
+  but it should manage to break a couple of things so you will
+  need a manual pass to fix things after that.
+  
+  Stephane Bailliez, sbailliez@apache.org
+  
+  -->
+  <xsl:output method="xml" indent="yes" doctype-system="document-v11.dtd"
+  doctype-public="-//APACHE//DTD Documentation V1.1//EN" encoding="ISO-8859-1"/>
+
+  <!-- properties = header in Forrest language -->
+  <xsl:template match="properties">
+    <header>
+      <xsl:apply-templates select="*[ local-name() != 'author']"/>
+      <author>
+        <xsl:apply-templates select="author"/>
+      </author>
+    </header>
+  </xsl:template>
+
+  <xsl:template match="author">
+    <person id="{text()}">
+      <!--
+      not everyone gives his mail in order not to receive too much spam... or be
+      assimilated as 24/24 7/7 support
+      -->
+      <xsl:if test="@email"><xsl:attribute name="email"><xsl:value-of select="@email"/></xsl:attribute></xsl:if>
+    </person>
+  </xsl:template>
+
+  <!-- section = subsection with forrest and the title is an element -->
+  <xsl:template match="section|subsection">
+    <section>
+      <title><xsl:value-of select="@name"/></title>
+      <xsl:apply-templates/>
+    </section>
+  </xsl:template>
+
+  <!-- Ignore those tags they should not be here, this will clean up
+  some but will break others, anyways. br is evil :) -->
+  <xsl:template match="br|nobr">
+    <xsl:apply-templates/>
+  </xsl:template>
+
+  <!-- font should not be there, it was used to do a source (or code ?)-->
+  <xsl:template match="font">
+    <source>
+      <xsl:apply-templates/>
+    </source>
+  </xsl:template>
+
+  <!-- assumes img = icon rather than figure -->
+  <xsl:template match="img">
+    <icon>
+    <xsl:apply-templates select="@alt|@src|@width|@height"/>
+    </icon>
+  </xsl:template>
+  
+  <!-- assume every anchor with a name is an anchor -->
+  <xsl:template match="a[@name]">
+    <anchor>
+      <xsl:apply-templates select="@*"/>
+      <xsl:apply-templates/>
+    </anchor>  
+  </xsl:template>
+  
+  <!-- try to be super smart to detect link/anchor/jump -->
+  <xsl:template match="a[@href]">
+    <xsl:choose>
+      <!-- something with a hashmark is a jump -->
+      <xsl:when test="starts-with(@href, '#')">
+        <jump>
+          <xsl:apply-templates select="@*"/>
+          <xsl:apply-templates/>        
+        </jump>
+      </xsl:when>
+      <!--
+        assume everything out of apache domain would be better with a fork
+        This is really a life style, I hate windows forking all over my
+        desktop but it's quite convenient sometimes when too lazy to shift.
+        One super thing would be to do like Microsoft.com and put an
+        extra icon via forrest after the link when it send outside
+        the apache site.
+      -->
+      <xsl:when test="starts-with(@href, 'http://') and not(contains(@href, 'apache.org'))">
+        <fork>
+          <xsl:apply-templates select="@*"/>
+          <xsl:apply-templates/>        
+        </fork>
+      </xsl:when>
+      <!-- fallback to a basic link -->
+      <xsl:otherwise>
+        <link>
+          <xsl:apply-templates select="@*"/>
+          <xsl:apply-templates/>
+        </link>
+      </xsl:otherwise>
+    </xsl:choose>
+  </xsl:template>
+
+  <!---
+    Ugly hack to define an axial table
+    The css could be defined as text-align:right !important;
+    -->
+  <xsl:template match="table">
+    <table>
+    <!--
+      (tr[1]/th and tr[1]/td) would give the same result
+      but I'm using following-sibbling to sound super smart
+      and obfuscate my code. It hard to write, so it should
+      be hard to understand ;-)
+      -->
+    <xsl:if test="tr[1]/th[following-sibling::td]">
+      <xsl:attribute name="class">axial</xsl:attribute>
+    </xsl:if>
+    <xsl:apply-templates select="@*"/>
+    <xsl:apply-templates/>
+    </table>
+  </xsl:template>
+
+<!-- wide rule, copy all nodes and attributes -->
+  <xsl:template match="node()|@*" priority="-1">
+    <xsl:copy>
+      <xsl:apply-templates select="@*"/>
+      <xsl:apply-templates/>
+    </xsl:copy>
+  </xsl:template>
+</xsl:stylesheet>
\ No newline at end of file
diff --git a/proposal/ant-site/forrest/build.xml b/proposal/ant-site/forrest/build.xml
new file mode 100644
index 000000000..fed24f07f
--- /dev/null
+++ b/proposal/ant-site/forrest/build.xml
@@ -0,0 +1,18 @@
+<project name="anakia2forrest" default="run" basedir=".">
+
+    <!-- Initialization properties -->
+    <property name="anakia.xdocs.src"     location="../anakia/xdocs"/>
+    <property name="docs.dest"    location="docs"/>
+
+    <!-- run forrest, run ! -->
+    <target name="run">      
+      <xslt force="true" basedir="${anakia.xdocs.src}" destdir="${docs.dest}"
+        includes="**/*.xml"
+        extension=".xml"
+        style="${basedir}/anakia2forrest.xsl"/>      
+      
+      <xslt force="true" in="${anakia.xdocs.src}/stylesheets/project.xml" out="${docs.dest}/book.xml"
+        style="${basedir}/project2book.xsl"/>
+    </target>
+
+</project>
diff --git a/proposal/ant-site/forrest/project2book.xsl b/proposal/ant-site/forrest/project2book.xsl
new file mode 100644
index 000000000..8ae084160
--- /dev/null
+++ b/proposal/ant-site/forrest/project2book.xsl
@@ -0,0 +1,36 @@
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
+<!--
+
+  A little bit of automated transformation to help conversion
+  from Anakia to Forrest/Cocoon docs.
+  
+  This is purely experimental, it hem...should work, well mostly
+  but it should manage to break a couple of things so you will
+  need a manual pass to fix things after that.
+  
+  Stephane Bailliez, sbailliez@apache.org
+  
+  -->
+  <xsl:output method="xml" indent="yes" doctype-system="book-cocoon-v10.dtd"
+  doctype-public="-//APACHE//DTD Cocoon Documentation Book V1.0//EN" encoding="ISO-8859-1"/>
+
+  <xsl:template match="project">
+    <book copyright="2002 The Apache Software Foundation"
+          xmlns:xlink="http://www.w3.org/1999/xlink"
+          software="{@name}"
+          title="{title/text()}">
+        <xsl:apply-templates select="body/menu"/>
+    </book>
+  </xsl:template>
+
+  <xsl:template match="menu">
+    <menu label="{@name}">
+        <xsl:apply-templates select="item"/>
+    </menu>
+  </xsl:template>
+
+  <xsl:template match="item">
+    <menu-item label="{@name}" href="{@href}"/>
+  </xsl:template>
+
+</xsl:stylesheet>
\ No newline at end of file