nihui
/
ncnn
Not watched
1
0
Fork 0
Code
Releases 46 Wiki evaluate Activity
Issues 0 Pull Requests 0 Datasets Model Cloudbrain HPC
You can not select more than 25 topics Topics must start with a chinese character,a letter or number, can include dashes ('-') and can be up to 35 characters long.
Tree: f1bdc87478
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'f1bdc87478'
${ noResults }
ncnn/cmake/ncnn_add_layer.cmake

409 lines
24 kB
Raw Blame History 

  1. 

  2. macro(ncnn_add_arch_opt_layer class NCNN_TARGET_ARCH_OPT NCNN_TARGET_ARCH_OPT_CFLAGS)

  3.     set(NCNN_${NCNN_TARGET_ARCH}_HEADER ${CMAKE_CURRENT_SOURCE_DIR}/layer/${NCNN_TARGET_ARCH}/${name}_${NCNN_TARGET_ARCH}.h)

  4.     set(NCNN_${NCNN_TARGET_ARCH}_SOURCE ${CMAKE_CURRENT_SOURCE_DIR}/layer/${NCNN_TARGET_ARCH}/${name}_${NCNN_TARGET_ARCH}.cpp)

  5. 

  6.     if(WITH_LAYER_${name} AND EXISTS ${NCNN_${NCNN_TARGET_ARCH}_HEADER} AND EXISTS ${NCNN_${NCNN_TARGET_ARCH}_SOURCE})

  7. 

  8.         set(NCNN_${NCNN_TARGET_ARCH_OPT}_HEADER ${CMAKE_CURRENT_BINARY_DIR}/layer/${NCNN_TARGET_ARCH}/${name}_${NCNN_TARGET_ARCH}_${NCNN_TARGET_ARCH_OPT}.h)

  9.         set(NCNN_${NCNN_TARGET_ARCH_OPT}_SOURCE ${CMAKE_CURRENT_BINARY_DIR}/layer/${NCNN_TARGET_ARCH}/${name}_${NCNN_TARGET_ARCH}_${NCNN_TARGET_ARCH_OPT}.cpp)

  10. 

  11.         add_custom_command(

  12.             OUTPUT ${NCNN_${NCNN_TARGET_ARCH_OPT}_HEADER}

  13.             COMMAND ${CMAKE_COMMAND} -DSRC=${NCNN_${NCNN_TARGET_ARCH}_HEADER} -DDST=${NCNN_${NCNN_TARGET_ARCH_OPT}_HEADER} -DCLASS=${class} -P "${CMAKE_CURRENT_SOURCE_DIR}/../cmake/ncnn_generate_${NCNN_TARGET_ARCH_OPT}_source.cmake"

  14.             DEPENDS ${NCNN_${NCNN_TARGET_ARCH}_HEADER}

  15.             COMMENT "Generating source ${name}_${NCNN_TARGET_ARCH}_${NCNN_TARGET_ARCH_OPT}.h"

  16.             VERBATIM

  17.         )

  18.         set_source_files_properties(${NCNN_${NCNN_TARGET_ARCH_OPT}_HEADER} PROPERTIES GENERATED TRUE)

  19. 

  20.         add_custom_command(

  21.             OUTPUT ${NCNN_${NCNN_TARGET_ARCH_OPT}_SOURCE}

  22.             COMMAND ${CMAKE_COMMAND} -DSRC=${NCNN_${NCNN_TARGET_ARCH}_SOURCE} -DDST=${NCNN_${NCNN_TARGET_ARCH_OPT}_SOURCE} -DCLASS=${class} -P "${CMAKE_CURRENT_SOURCE_DIR}/../cmake/ncnn_generate_${NCNN_TARGET_ARCH_OPT}_source.cmake"

  23.             DEPENDS ${NCNN_${NCNN_TARGET_ARCH}_SOURCE}

  24.             COMMENT "Generating source ${name}_${NCNN_TARGET_ARCH}_${NCNN_TARGET_ARCH_OPT}.cpp"

  25.             VERBATIM

  26.         )

  27.         set_source_files_properties(${NCNN_${NCNN_TARGET_ARCH_OPT}_SOURCE} PROPERTIES GENERATED TRUE)

  28. 

  29.         set_source_files_properties(${NCNN_${NCNN_TARGET_ARCH_OPT}_SOURCE} PROPERTIES COMPILE_FLAGS ${NCNN_TARGET_ARCH_OPT_CFLAGS})

  30. 

  31.         list(APPEND ncnn_SRCS ${NCNN_${NCNN_TARGET_ARCH_OPT}_HEADER} ${NCNN_${NCNN_TARGET_ARCH_OPT}_SOURCE})

  32. 

  33.         # generate layer_declaration and layer_registry file

  34.         set(layer_declaration "${layer_declaration}#include \"layer/${NCNN_TARGET_ARCH}/${name}_${NCNN_TARGET_ARCH}_${NCNN_TARGET_ARCH_OPT}.h\"\n")

  35.         set(layer_declaration "${layer_declaration}namespace ncnn { DEFINE_LAYER_CREATOR(${class}_${NCNN_TARGET_ARCH}_${NCNN_TARGET_ARCH_OPT}) }\n")

  36. 

  37.         set(layer_registry_${NCNN_TARGET_ARCH_OPT} "${layer_registry_${NCNN_TARGET_ARCH_OPT}}#if NCNN_STRING\n{\"${class}\", ${class}_${NCNN_TARGET_ARCH}_${NCNN_TARGET_ARCH_OPT}_layer_creator},\n#else\n{${class}_${NCNN_TARGET_ARCH}_${NCNN_TARGET_ARCH_OPT}_layer_creator},\n#endif\n")

  38.     else()

  39.         # no isa optimized version

  40.         if(WITH_LAYER_${name})

  41.             set(layer_registry_${NCNN_TARGET_ARCH_OPT} "${layer_registry_${NCNN_TARGET_ARCH_OPT}}#if NCNN_STRING\n{\"${class}\", ${class}_layer_creator},\n#else\n{${class}_layer_creator},\n#endif\n")

  42.         else()

  43.             set(layer_registry_${NCNN_TARGET_ARCH_OPT} "${layer_registry_${NCNN_TARGET_ARCH_OPT}}#if NCNN_STRING\n{\"${class}\", 0},\n#else\n{0},\n#endif\n")

  44.         endif()

  45.     endif()

  46. endmacro()

  47. 

  48. macro(ncnn_add_arch_opt_source class NCNN_TARGET_ARCH_OPT NCNN_TARGET_ARCH_OPT_CFLAGS)

  49.     set(NCNN_${NCNN_TARGET_ARCH_OPT}_SOURCE ${CMAKE_CURRENT_SOURCE_DIR}/layer/${NCNN_TARGET_ARCH}/${name}_${NCNN_TARGET_ARCH}_${NCNN_TARGET_ARCH_OPT}.cpp)

  50. 

  51.     if(WITH_LAYER_${name} AND EXISTS ${NCNN_${NCNN_TARGET_ARCH_OPT}_SOURCE})

  52.         set_source_files_properties(${NCNN_${NCNN_TARGET_ARCH_OPT}_SOURCE} PROPERTIES COMPILE_FLAGS ${NCNN_TARGET_ARCH_OPT_CFLAGS})

  53.         list(APPEND ncnn_SRCS ${NCNN_${NCNN_TARGET_ARCH_OPT}_SOURCE})

  54.     endif()

  55. endmacro()

  56. 

  57. macro(ncnn_add_layer class)

  58.     string(TOLOWER ${class} name)

  59. 

  60.     # WITH_LAYER_xxx option

  61.     if(${ARGC} EQUAL 2)

  62.         option(WITH_LAYER_${name} "build with layer ${name}" ${ARGV1})

  63.     else()

  64.         option(WITH_LAYER_${name} "build with layer ${name}" ON)

  65.     endif()

  66. 

  67.     if(NCNN_CMAKE_VERBOSE)

  68.         message(STATUS "WITH_LAYER_${name} = ${WITH_LAYER_${name}}")

  69.     endif()

  70. 

  71.     if(WITH_LAYER_${name})

  72.         list(APPEND ncnn_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/layer/${name}.cpp)

  73. 

  74.         # look for arch specific implementation and append source

  75.         # optimized implementation for armv7, aarch64 or x86

  76.         set(LAYER_ARCH_SRC ${CMAKE_CURRENT_SOURCE_DIR}/layer/${NCNN_TARGET_ARCH}/${name}_${NCNN_TARGET_ARCH}.cpp)

  77.         if(EXISTS ${LAYER_ARCH_SRC})

  78.             set(WITH_LAYER_${name}_${NCNN_TARGET_ARCH} 1)

  79.             list(APPEND ncnn_SRCS ${LAYER_ARCH_SRC})

  80.         endif()

  81. 

  82.         set(LAYER_VULKAN_SRC ${CMAKE_CURRENT_SOURCE_DIR}/layer/vulkan/${name}_vulkan.cpp)

  83.         if(NCNN_VULKAN AND EXISTS ${LAYER_VULKAN_SRC})

  84.             set(WITH_LAYER_${name}_vulkan 1)

  85.             list(APPEND ncnn_SRCS ${LAYER_VULKAN_SRC})

  86.         endif()

  87.     endif()

  88. 

  89.     # generate layer_declaration and layer_registry file

  90.     if(WITH_LAYER_${name})

  91.         set(layer_declaration "${layer_declaration}#include \"layer/${name}.h\"\n")

  92.         set(layer_declaration "${layer_declaration}namespace ncnn { DEFINE_LAYER_CREATOR(${class}) }\n")

  93. 

  94.         source_group ("sources\\\\layers" FILES "${CMAKE_CURRENT_SOURCE_DIR}/layer/${name}.cpp")

  95.     endif()

  96. 

  97.     if(WITH_LAYER_${name}_${NCNN_TARGET_ARCH})

  98.         set(layer_declaration "${layer_declaration}#include \"layer/${NCNN_TARGET_ARCH}/${name}_${NCNN_TARGET_ARCH}.h\"\n")

  99.         set(layer_declaration "${layer_declaration}namespace ncnn { DEFINE_LAYER_CREATOR(${class}_${NCNN_TARGET_ARCH}) }\n")

  100. 

  101.         source_group ("sources\\\\layers\\\\${NCNN_TARGET_ARCH}" FILES "${CMAKE_CURRENT_SOURCE_DIR}/layer/${NCNN_TARGET_ARCH}/${name}_${NCNN_TARGET_ARCH}.cpp")

  102.     endif()

  103. 

  104.     if(WITH_LAYER_${name}_vulkan)

  105.         set(layer_declaration "${layer_declaration}#include \"layer/vulkan/${name}_vulkan.h\"\n")

  106.         set(layer_declaration "${layer_declaration}namespace ncnn { DEFINE_LAYER_CREATOR(${class}_vulkan) }\n")

  107. 

  108.         file(GLOB_RECURSE NCNN_SHADER_SRCS "layer/vulkan/shader/${name}.comp")

  109.         file(GLOB_RECURSE NCNN_SHADER_SUBSRCS "layer/vulkan/shader/${name}_*.comp")

  110.         list(APPEND NCNN_SHADER_SRCS ${NCNN_SHADER_SUBSRCS})

  111.         foreach(NCNN_SHADER_SRC ${NCNN_SHADER_SRCS})

  112.             ncnn_add_shader(${NCNN_SHADER_SRC})

  113.         endforeach()

  114. 

  115.         source_group ("sources\\\\layers\\\\vulkan" FILES "${CMAKE_CURRENT_SOURCE_DIR}/layer/vulkan/${name}_vulkan.cpp")

  116.     endif()

  117. 

  118.     if(WITH_LAYER_${name})

  119.         set(layer_registry "${layer_registry}#if NCNN_STRING\n{\"${class}\", ${class}_layer_creator},\n#else\n{${class}_layer_creator},\n#endif\n")

  120.     else()

  121.         set(layer_registry "${layer_registry}#if NCNN_STRING\n{\"${class}\", 0},\n#else\n{0},\n#endif\n")

  122.     endif()

  123. 

  124.     if(WITH_LAYER_${name}_${NCNN_TARGET_ARCH})

  125.         set(layer_registry_arch "${layer_registry_arch}#if NCNN_STRING\n{\"${class}\", ${class}_${NCNN_TARGET_ARCH}_layer_creator},\n#else\n{${class}_${NCNN_TARGET_ARCH}_layer_creator},\n#endif\n")

  126.     else()

  127.         set(layer_registry_arch "${layer_registry_arch}#if NCNN_STRING\n{\"${class}\", 0},\n#else\n{0},\n#endif\n")

  128.     endif()

  129. 

  130.     if(WITH_LAYER_${name}_vulkan)

  131.         set(layer_registry_vulkan "${layer_registry_vulkan}#if NCNN_STRING\n{\"${class}\", ${class}_vulkan_layer_creator},\n#else\n{${class}_vulkan_layer_creator},\n#endif\n")

  132.     else()

  133.         set(layer_registry_vulkan "${layer_registry_vulkan}#if NCNN_STRING\n{\"${class}\", 0},\n#else\n{0},\n#endif\n")

  134.     endif()

  135. 

  136.     if(NCNN_TARGET_ARCH STREQUAL "x86")

  137.         if(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")

  138.             if(NCNN_RUNTIME_CPU AND NCNN_AVX512)

  139.                 ncnn_add_arch_opt_layer(${class} avx512 "/arch:AVX512 /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__")

  140.             endif()

  141.             if(NCNN_RUNTIME_CPU AND NCNN_FMA)

  142.                 ncnn_add_arch_opt_layer(${class} fma "/arch:AVX /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__")

  143.             endif()

  144.             if(NCNN_RUNTIME_CPU AND NCNN_AVX)

  145.                 ncnn_add_arch_opt_layer(${class} avx "/arch:AVX /D__SSSE3__ /D__SSE4_1__")

  146.             endif()

  147.             if(NCNN_RUNTIME_CPU AND NCNN_AVX512VNNI)

  148.                 ncnn_add_arch_opt_source(${class} avx512vnni "/arch:AVX512 /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__ /D__AVX512VNNI__")

  149.             endif()

  150.             if(NCNN_RUNTIME_CPU AND NCNN_AVX512BF16)

  151.                 ncnn_add_arch_opt_source(${class} avx512bf16 "/arch:AVX512 /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__ /D__AVX512BF16__")

  152.             endif()

  153.             if(NCNN_RUNTIME_CPU AND NCNN_AVX512FP16)

  154.                 ncnn_add_arch_opt_source(${class} avx512fp16 "/arch:AVX512 /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__ /D__AVX512FP16__")

  155.             endif()

  156.             if(NCNN_RUNTIME_CPU AND NCNN_AVXVNNI)

  157.                 ncnn_add_arch_opt_source(${class} avxvnni "/arch:AVX2 /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__ /D__AVXVNNI__")

  158.             endif()

  159.             if(NCNN_RUNTIME_CPU AND NCNN_AVXVNNIINT8)

  160.                 ncnn_add_arch_opt_source(${class} avxvnniint8 "/arch:AVX2 /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__ /D__AVXVNNI__ /D__AVXVNNIINT8__")

  161.             endif()

  162.             if(NCNN_RUNTIME_CPU AND NCNN_AVXVNNIINT16)

  163.                 ncnn_add_arch_opt_source(${class} avxvnniint16 "/arch:AVX2 /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__ /D__AVXVNNI__ /D__AVXVNNIINT16__")

  164.             endif()

  165.             if(NCNN_RUNTIME_CPU AND NCNN_AVXNECONVERT)

  166.                 ncnn_add_arch_opt_source(${class} avxneconvert "/arch:AVX2 /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__ /D__AVXNECONVERT__")

  167.             endif()

  168.             if(NCNN_RUNTIME_CPU AND NCNN_AVX2)

  169.                 ncnn_add_arch_opt_source(${class} avx2 "/arch:AVX2 /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__")

  170.             endif()

  171.             if(NCNN_RUNTIME_CPU AND NCNN_XOP)

  172.                 ncnn_add_arch_opt_source(${class} xop "/arch:AVX /D__SSSE3__ /D__SSE4_1__ /D__XOP__")

  173.             endif()

  174.             if(NCNN_RUNTIME_CPU AND NCNN_F16C)

  175.                 ncnn_add_arch_opt_source(${class} f16c "/arch:AVX /D__SSSE3__ /D__SSE4_1__ /D__F16C__")

  176.             endif()

  177.         elseif(CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_SIMULATE_ID MATCHES "MSVC" AND CMAKE_CXX_COMPILER_FRONTEND_VARIANT MATCHES "MSVC")

  178.             if(NCNN_RUNTIME_CPU AND NCNN_AVX512)

  179.                 ncnn_add_arch_opt_layer(${class} avx512 "/arch:AVX512 -mavx512cd -mavx512bw -mavx512dq -mavx512vl -mfma -mf16c /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__")

  180.             endif()

  181.             if(NCNN_RUNTIME_CPU AND NCNN_FMA)

  182.                 ncnn_add_arch_opt_layer(${class} fma "/arch:AVX -mfma -mf16c /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__")

  183.             endif()

  184.             if(NCNN_RUNTIME_CPU AND NCNN_AVX)

  185.                 ncnn_add_arch_opt_layer(${class} avx "/arch:AVX /D__SSSE3__ /D__SSE4_1__")

  186.             endif()

  187.             if(NCNN_RUNTIME_CPU AND NCNN_AVX512VNNI)

  188.                 ncnn_add_arch_opt_source(${class} avx512vnni "/arch:AVX512 -mavx512cd -mavx512bw -mavx512dq -mavx512vl -mfma -mf16c -mavx512vnni /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__ /D__AVX512VNNI__")

  189.             endif()

  190.             if(NCNN_RUNTIME_CPU AND NCNN_AVX512BF16)

  191.                 ncnn_add_arch_opt_source(${class} avx512bf16 "/arch:AVX512 -mavx512cd -mavx512bw -mavx512dq -mavx512vl -mfma -mf16c -mavx512bf16 /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__ /D__AVX512BF16__")

  192.             endif()

  193.             if(NCNN_RUNTIME_CPU AND NCNN_AVX512FP16)

  194.                 ncnn_add_arch_opt_source(${class} avx512fp16 "/arch:AVX512 -mavx512cd -mavx512bw -mavx512dq -mavx512vl -mfma -mf16c -mavx512fp16 /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__ /D__AVX512FP16__")

  195.             endif()

  196.             if(NCNN_RUNTIME_CPU AND NCNN_AVXVNNI)

  197.                 ncnn_add_arch_opt_source(${class} avxvnni "/arch:AVX2 -mfma -mf16c -mavxvnni /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__ /D__AVXVNNI__")

  198.             endif()

  199.             if(NCNN_RUNTIME_CPU AND NCNN_AVXVNNIINT8)

  200.                 ncnn_add_arch_opt_source(${class} avxvnniint8 "/arch:AVX2 -mfma -mf16c -mavxvnni -mavxvnniint8 /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__ /D__AVXVNNI__ /D__AVXVNNIINT8__")

  201.             endif()

  202.             if(NCNN_RUNTIME_CPU AND NCNN_AVXVNNIINT16)

  203.                 ncnn_add_arch_opt_source(${class} avxvnniint16 "/arch:AVX2 -mfma -mf16c -mavxvnni -mavxvnniint16 /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__ /D__AVXVNNI__ /D__AVXVNNIINT16__")

  204.             endif()

  205.             if(NCNN_RUNTIME_CPU AND NCNN_AVXNECONVERT)

  206.                 ncnn_add_arch_opt_source(${class} avxneconvert "/arch:AVX2 -mfma -mf16c -mavxneconvert /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__ /D__AVXNECONVERT__")

  207.             endif()

  208.             if(NCNN_RUNTIME_CPU AND NCNN_AVX2)

  209.                 ncnn_add_arch_opt_source(${class} avx2 "/arch:AVX2 -mfma -mf16c /D__SSSE3__ /D__SSE4_1__ /D__FMA__ /D__F16C__")

  210.             endif()

  211.             if(NCNN_RUNTIME_CPU AND NCNN_XOP)

  212.                 ncnn_add_arch_opt_source(${class} xop "/arch:AVX -mxop /D__SSSE3__ /D__SSE4_1__ /D__XOP__")

  213.             endif()

  214.             if(NCNN_RUNTIME_CPU AND NCNN_F16C)

  215.                 ncnn_add_arch_opt_source(${class} f16c "/arch:AVX -mf16c /D__SSSE3__ /D__SSE4_1__ /D__F16C__")

  216.             endif()

  217.         else()

  218.             if(NCNN_RUNTIME_CPU AND NCNN_AVX512)

  219.                 ncnn_add_arch_opt_layer(${class} avx512 "-mavx512f -mavx512cd -mavx512bw -mavx512dq -mavx512vl -mfma -mf16c")

  220.             endif()

  221.             if(NCNN_RUNTIME_CPU AND NCNN_FMA)

  222.                 ncnn_add_arch_opt_layer(${class} fma "-mavx -mfma -mf16c")

  223.             endif()

  224.             if(NCNN_RUNTIME_CPU AND NCNN_AVX)

  225.                 ncnn_add_arch_opt_layer(${class} avx "-mavx")

  226.             endif()

  227.             if(NCNN_RUNTIME_CPU AND NCNN_AVX512VNNI)

  228.                 ncnn_add_arch_opt_source(${class} avx512vnni "-mavx512f -mavx512cd -mavx512bw -mavx512dq -mavx512vl -mfma -mf16c -mavx512vnni")

  229.             endif()

  230.             if(NCNN_RUNTIME_CPU AND NCNN_AVX512BF16)

  231.                 ncnn_add_arch_opt_source(${class} avx512bf16 "-mavx512f -mavx512cd -mavx512bw -mavx512dq -mavx512vl -mfma -mf16c -mavx512bf16")

  232.             endif()

  233.             if(NCNN_RUNTIME_CPU AND NCNN_AVX512FP16)

  234.                 ncnn_add_arch_opt_source(${class} avx512fp16 "-mavx512f -mavx512cd -mavx512bw -mavx512dq -mavx512vl -mfma -mf16c -mavx512fp16")

  235.             endif()

  236.             if(NCNN_RUNTIME_CPU AND NCNN_AVXVNNI)

  237.                 ncnn_add_arch_opt_source(${class} avxvnni "-mavx2 -mfma -mf16c -mavxvnni")

  238.             endif()

  239.             if(NCNN_RUNTIME_CPU AND NCNN_AVXVNNIINT8)

  240.                 ncnn_add_arch_opt_source(${class} avxvnniint8 "-mavx2 -mfma -mf16c -mavxvnni -mavxvnniint8")

  241.             endif()

  242.             if(NCNN_RUNTIME_CPU AND NCNN_AVXVNNIINT16)

  243.                 ncnn_add_arch_opt_source(${class} avxvnniint16 "-mavx2 -mfma -mf16c -mavxvnni -mavxvnniint16")

  244.             endif()

  245.             if(NCNN_RUNTIME_CPU AND NCNN_AVXNECONVERT)

  246.                 ncnn_add_arch_opt_source(${class} avxneconvert "-mavx2 -mfma -mf16c -mavxneconvert")

  247.             endif()

  248.             if(NCNN_RUNTIME_CPU AND NCNN_AVX2)

  249.                 ncnn_add_arch_opt_source(${class} avx2 "-mavx2 -mfma -mf16c")

  250.             endif()

  251.             if(NCNN_RUNTIME_CPU AND NCNN_XOP)

  252.                 ncnn_add_arch_opt_source(${class} xop "-mavx -mxop")

  253.             endif()

  254.             if(NCNN_RUNTIME_CPU AND NCNN_F16C)

  255.                 ncnn_add_arch_opt_source(${class} f16c "-mavx -mf16c")

  256.             endif()

  257.         endif()

  258.     endif()

  259. 

  260.     if(NCNN_TARGET_ARCH STREQUAL "arm" AND (CMAKE_SIZEOF_VOID_P EQUAL 4 AND NOT NCNN_TARGET_ILP32))

  261.         if(CMAKE_CXX_COMPILER_ID MATCHES "MSVC" OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_SIMULATE_ID MATCHES "MSVC" AND CMAKE_CXX_COMPILER_FRONTEND_VARIANT MATCHES "MSVC"))

  262.             if(NCNN_VFPV4)

  263.                 ncnn_add_arch_opt_source(${class} vfpv4 "/arch:VFPv4 /D__ARM_FP=0x0E")

  264.             endif()

  265.         else()

  266.             if(NCNN_VFPV4)

  267.                 if(NCNN_COMPILER_SUPPORT_ARM_VFPV4)

  268.                     ncnn_add_arch_opt_source(${class} vfpv4 "-mfpu=neon-vfpv4")

  269.                 elseif(NCNN_COMPILER_SUPPORT_ARM_VFPV4_FP16)

  270.                     ncnn_add_arch_opt_source(${class} vfpv4 "-mfpu=neon-vfpv4 -mfp16-format=ieee")

  271.                 endif()

  272.             endif()

  273.         endif()

  274.     endif()

  275. 

  276.     if(NCNN_TARGET_ARCH STREQUAL "arm" AND (CMAKE_SIZEOF_VOID_P EQUAL 8 OR NCNN_TARGET_ILP32))

  277.         if(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")

  278.             if(NCNN_VFPV4)

  279.                 ncnn_add_arch_opt_source(${class} vfpv4 " ")

  280.             endif()

  281.             if(NCNN_ARM82)

  282.                 ncnn_add_arch_opt_source(${class} asimdhp "/arch:armv8.2 /D__ARM_FEATURE_FP16_VECTOR_ARITHMETIC")

  283.             endif()

  284.             if(NCNN_RUNTIME_CPU AND NCNN_ARM82DOT)

  285.                 ncnn_add_arch_opt_source(${class} asimddp "/arch:armv8.2 /D__ARM_FEATURE_FP16_VECTOR_ARITHMETIC /D__ARM_FEATURE_DOTPROD")

  286.             endif()

  287.             if(NCNN_RUNTIME_CPU AND NCNN_ARM82FP16FML)

  288.                 ncnn_add_arch_opt_source(${class} asimdfhm "/arch:armv8.2 /D__ARM_FEATURE_FP16_VECTOR_ARITHMETIC /D__ARM_FEATURE_FP16_FML")

  289.             endif()

  290.             if(NCNN_RUNTIME_CPU AND NCNN_ARM84BF16)

  291.                 ncnn_add_arch_opt_source(${class} bf16 "/arch:armv8.4 /D__ARM_FEATURE_FP16_VECTOR_ARITHMETIC /D__ARM_FEATURE_DOTPROD /D__ARM_FEATURE_FP16_FML /D__ARM_FEATURE_BF16_VECTOR_ARITHMETIC")

  292.             endif()

  293.             if(NCNN_RUNTIME_CPU AND NCNN_ARM84I8MM)

  294.                 ncnn_add_arch_opt_source(${class} i8mm "/arch:armv8.4 /D__ARM_FEATURE_FP16_VECTOR_ARITHMETIC /D__ARM_FEATURE_DOTPROD /D__ARM_FEATURE_FP16_FML /D__ARM_FEATURE_MATMUL_INT8")

  295.             endif()

  296.             # TODO add support for sve family

  297.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVE)

  298.             endif()

  299.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVE2)

  300.             endif()

  301.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVEBF16)

  302.             endif()

  303.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVEI8MM)

  304.             endif()

  305.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVEF32MM)

  306.             endif()

  307.         elseif(CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_SIMULATE_ID MATCHES "MSVC" AND CMAKE_CXX_COMPILER_FRONTEND_VARIANT MATCHES "MSVC")

  308.             if(NCNN_VFPV4)

  309.                 ncnn_add_arch_opt_source(${class} vfpv4 " ")

  310.             endif()

  311.             if(NCNN_ARM82)

  312.                 ncnn_add_arch_opt_source(${class} asimdhp "/arch:armv8.2 -march=armv8.2-a+fp16 /D__ARM_FEATURE_FP16_VECTOR_ARITHMETIC")

  313.             endif()

  314.             if(NCNN_RUNTIME_CPU AND NCNN_ARM82DOT)

  315.                 ncnn_add_arch_opt_source(${class} asimddp "/arch:armv8.2 -march=armv8.2-a+fp16+dotprod /D__ARM_FEATURE_FP16_VECTOR_ARITHMETIC /D__ARM_FEATURE_DOTPROD")

  316.             endif()

  317.             if(NCNN_RUNTIME_CPU AND NCNN_ARM82FP16FML)

  318.                 ncnn_add_arch_opt_source(${class} asimdfhm "/arch:armv8.2 -march=armv8.2-a+fp16+fp16fml /D__ARM_FEATURE_FP16_VECTOR_ARITHMETIC /D__ARM_FEATURE_FP16_FML")

  319.             endif()

  320.             if(NCNN_RUNTIME_CPU AND NCNN_ARM84BF16)

  321.                 ncnn_add_arch_opt_source(${class} bf16 "/arch:armv8.4 -march=armv8.4-a+fp16+dotprod+bf16 /D__ARM_FEATURE_FP16_VECTOR_ARITHMETIC /D__ARM_FEATURE_DOTPROD /D__ARM_FEATURE_FP16_FML /D__ARM_FEATURE_BF16_VECTOR_ARITHMETIC")

  322.             endif()

  323.             if(NCNN_RUNTIME_CPU AND NCNN_ARM84I8MM)

  324.                 ncnn_add_arch_opt_source(${class} i8mm "/arch:armv8.4 -march=armv8.4-a+fp16+dotprod+i8mm /D__ARM_FEATURE_FP16_VECTOR_ARITHMETIC /D__ARM_FEATURE_DOTPROD /D__ARM_FEATURE_FP16_FML /D__ARM_FEATURE_MATMUL_INT8")

  325.             endif()

  326.             # TODO add support for sve family

  327.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVE)

  328.             endif()

  329.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVE2)

  330.             endif()

  331.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVEBF16)

  332.             endif()

  333.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVEI8MM)

  334.             endif()

  335.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVEF32MM)

  336.             endif()

  337.         else()

  338.             if(NCNN_VFPV4)

  339.                 ncnn_add_arch_opt_source(${class} vfpv4 " ")

  340.             endif()

  341.             if(NCNN_ARM82)

  342.                 ncnn_add_arch_opt_source(${class} asimdhp "-march=armv8.2-a+fp16")

  343.             endif()

  344.             if(NCNN_RUNTIME_CPU AND NCNN_ARM82DOT)

  345.                 ncnn_add_arch_opt_source(${class} asimddp "-march=armv8.2-a+fp16+dotprod")

  346.             endif()

  347.             if(NCNN_RUNTIME_CPU AND NCNN_ARM82FP16FML)

  348.                 # clang 9.0.9 shipped with android ndk-r21 is missing __ARM_FEATURE_FP16_FML macro for asimdfhm target

  349.                 ncnn_add_arch_opt_source(${class} asimdfhm "-march=armv8.2-a+fp16+fp16fml -D__ARM_FEATURE_FP16_FML")

  350.             endif()

  351.             if(NCNN_RUNTIME_CPU AND NCNN_ARM84BF16)

  352.                 ncnn_add_arch_opt_source(${class} bf16 "-march=armv8.4-a+fp16+dotprod+bf16")

  353.             endif()

  354.             if(NCNN_RUNTIME_CPU AND NCNN_ARM84I8MM)

  355.                 ncnn_add_arch_opt_source(${class} i8mm "-march=armv8.4-a+fp16+dotprod+i8mm")

  356.             endif()

  357.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVE)

  358.                 ncnn_add_arch_opt_source(${class} sve "-march=armv8.6-a+fp16+dotprod+sve")

  359.             endif()

  360.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVE2)

  361.                 ncnn_add_arch_opt_source(${class} sve2 "-march=armv8.6-a+fp16+dotprod+sve2")

  362.             endif()

  363.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVEBF16)

  364.                 ncnn_add_arch_opt_source(${class} svebf16 "-march=armv8.6-a+fp16+dotprod+sve+bf16")

  365.             endif()

  366.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVEI8MM)

  367.                 ncnn_add_arch_opt_source(${class} svei8mm "-march=armv8.6-a+fp16+dotprod+sve+i8mm")

  368.             endif()

  369.             if(NCNN_RUNTIME_CPU AND NCNN_ARM86SVEF32MM)

  370.                 ncnn_add_arch_opt_source(${class} svef32mm "-march=armv8.6-a+fp16+dotprod+sve+f32mm")

  371.             endif()

  372.         endif()

  373.     endif()

  374. 

  375.     if(NCNN_TARGET_ARCH STREQUAL "mips")

  376.         if(NCNN_RUNTIME_CPU AND NCNN_MSA)

  377.             ncnn_add_arch_opt_layer(${class} msa "-mmsa")

  378.         endif()

  379.         if(NCNN_MMI)

  380.             ncnn_add_arch_opt_source(${class} mmi "-mloongson-mmi")

  381.         endif()

  382.     endif()

  383. 

  384.     if(NCNN_TARGET_ARCH STREQUAL "loongarch")

  385.         if(NCNN_RUNTIME_CPU AND NCNN_LASX)

  386.             ncnn_add_arch_opt_layer(${class} lasx "-mlasx -mlsx")

  387.         endif()

  388.         if(NCNN_RUNTIME_CPU AND NCNN_LSX)

  389.             ncnn_add_arch_opt_layer(${class} lsx "-mlsx")

  390.         endif()

  391.     endif()

  392. 

  393.     if(NCNN_TARGET_ARCH STREQUAL "riscv" AND CMAKE_SIZEOF_VOID_P EQUAL 8)

  394.         if(NCNN_RUNTIME_CPU AND NCNN_RVV)

  395.             if(NCNN_COMPILER_SUPPORT_RVV_ZFH)

  396.                 ncnn_add_arch_opt_layer(${class} rvv "-march=rv64gcv_zfh")

  397.             elseif(NCNN_COMPILER_SUPPORT_RVV_ZVFH)

  398.                 ncnn_add_arch_opt_layer(${class} rvv "-march=rv64gcv_zfh_zvfh0p1 -menable-experimental-extensions -D__fp16=_Float16")

  399.             elseif(NCNN_COMPILER_SUPPORT_RVV)

  400.                 ncnn_add_arch_opt_layer(${class} rvv "-march=rv64gcv")

  401.             endif()

  402.         endif()

  403.     endif()

  404. 

  405.     # generate layer_type_enum file

  406.     set(layer_type_enum "${layer_type_enum}${class} = ${__LAYER_TYPE_ENUM_INDEX},\n")

  407.     math(EXPR __LAYER_TYPE_ENUM_INDEX "${__LAYER_TYPE_ENUM_INDEX}+1")

  408. endmacro()