ncnn/src/layer/vulkan/shader/reshape_pack1to8.comp

// Tencent is pleased to support the open source community by making ncnn available.
//
// Copyright (C) 2020 THL A29 Limited, a Tencent company. All rights reserved.
//
// Licensed under the BSD 3-Clause License (the "License"); you may not use this file except
// in compliance with the License. You may obtain a copy of the License at
//
// https://opensource.org/licenses/BSD-3-Clause
//
// Unless required by applicable law or agreed to in writing, software distributed
// under the License is distributed on an "AS IS" BASIS, WITHOUT WARRANTIES OR
// CONDITIONS OF ANY KIND, either express or implied. See the License for the
// specific language governing permissions and limitations under the License.

#version 450

#if NCNN_fp16_storage
#extension GL_EXT_shader_16bit_storage: require
struct sfpvec8 { f16vec4 abcd; f16vec4 efgh; };
#endif
#if NCNN_fp16_arithmetic
#extension GL_EXT_shader_explicit_arithmetic_types_float16: require
#endif

layout (constant_id = 0) const int ndim = 0;

layout (local_size_x_id = 233) in;
layout (local_size_y_id = 234) in;
layout (local_size_z_id = 235) in;

layout (binding = 0) readonly buffer bottom_blob { sfp bottom_blob_data[]; };
layout (binding = 1) writeonly buffer top_blob { sfpvec8 top_blob_data[]; };

layout (push_constant) uniform parameter
{
    int dims;
    int w;
    int h;
    int c;
    int cstep;

    int outdims;
    int outw;
    int outh;
    int outc;
    int outcstep;
} p;

void main()
{
    int gx = int(gl_GlobalInvocationID.x);
    int gy = int(gl_GlobalInvocationID.y);
    int gz = int(gl_GlobalInvocationID.z);

    if (gx >= p.outw || gy >= p.outh || gz >= p.outc)
        return;

    ivec4 i4;
    ivec4 ii4;

    if (ndim == 1)
    {
        i4 = gx * 8 + ivec4(0, 1, 2, 3);
        ii4 = i4 + 4;
    }
    if (ndim == 2)
    {
        i4 = (gy * 8) * p.outw + gx + ivec4(0, 1, 2, 3) * p.outw;
        ii4 = i4 + 4 * p.outw;
    }
    if (ndim == 3)
    {
        i4 = (gz * 8) * p.outh * p.outw + gy * p.outw + gx + ivec4(0, 1, 2, 3) * p.outh * p.outw;
        ii4 = i4 + 4 * p.outh * p.outw;
    }

    int size = p.w * p.h;

    ivec4 z4 = i4 / size;
    ivec4 y4 = i4 % size / p.w;
    ivec4 x4 = i4 % size % p.w;
    ivec4 zz4 = ii4 / size;
    ivec4 yy4 = ii4 % size / p.w;
    ivec4 xx4 = ii4 % size % p.w;

    ivec4 v_offset = z4 * p.cstep + y4 * p.w + x4;
    ivec4 vv_offset = zz4 * p.cstep + yy4 * p.w + xx4;

    int gi = gz * p.outcstep + gy * p.outw + gx;

    buffer_cp1to8(top_blob_data, gi, bottom_blob_data, v_offset, vv_offset);
}