added optimized blas level1 dot kernels for single and double precision

kernel/arm/KERNEL.ARMV7

@@ -45,13 +45,13 @@ DAXPYKERNEL  = ../arm/axpy.c
 CAXPYKERNEL  = ../arm/zaxpy.c
 ZAXPYKERNEL  = ../arm/zaxpy.c
 
-SCOPYKERNEL  = ../arm/copy.c
-DCOPYKERNEL  = ../arm/copy.c
-CCOPYKERNEL  = ../arm/zcopy.c
-ZCOPYKERNEL  = ../arm/zcopy.c
+SCOPYKERNEL  = scopy_vfpv3.S
+DCOPYKERNEL  = dcopy_vfpv3.S
+CCOPYKERNEL  = ccopy_vfpv3.S
+ZCOPYKERNEL  = zcopy_vfpv3.S
 
-SDOTKERNEL   = ../arm/dot.c
-DDOTKERNEL   = ../arm/dot.c
+SDOTKERNEL   = sdot_vfpv3.S
+DDOTKERNEL   = ddot_vfpv3.S
 CDOTKERNEL   = ../arm/zdot.c
 ZDOTKERNEL   = ../arm/zdot.c
 
@@ -108,15 +108,15 @@ DGEMMOTCOPYOBJ = dgemm_otcopy.o
 
 CGEMMKERNEL    = cgemm_kernel_2x2_vfpv3.S
 CGEMMONCOPY    = cgemm_ncopy_2_vfpv3.S
-CGEMMOTCOPY    = ../generic/zgemm_tcopy_2.c
-CGEMMONCOPYOBJ =  cgemm_oncopy.o
-CGEMMOTCOPYOBJ =  cgemm_otcopy.o
+CGEMMOTCOPY    = cgemm_tcopy_2_vfpv3.S
+CGEMMONCOPYOBJ = cgemm_oncopy.o
+CGEMMOTCOPYOBJ = cgemm_otcopy.o
 
 ZGEMMKERNEL    = zgemm_kernel_2x2_vfpv3.S
 ZGEMMONCOPY    = zgemm_ncopy_2_vfpv3.S
-ZGEMMOTCOPY    = ../generic/zgemm_tcopy_2.c
-ZGEMMONCOPYOBJ =  zgemm_oncopy.o
-ZGEMMOTCOPYOBJ =  zgemm_otcopy.o
+ZGEMMOTCOPY    = zgemm_tcopy_2_vfpv3.S
+ZGEMMONCOPYOBJ = zgemm_oncopy.o
+ZGEMMOTCOPYOBJ = zgemm_otcopy.o
 
 STRSMKERNEL_LN	=  ../generic/trsm_kernel_LN.c
 STRSMKERNEL_LT	=  ../generic/trsm_kernel_LT.c
@@ -138,9 +138,4 @@ ZTRSMKERNEL_LT	= ../generic/trsm_kernel_LT.c
 ZTRSMKERNEL_RN	= ../generic/trsm_kernel_RN.c
 ZTRSMKERNEL_RT	= ../generic/trsm_kernel_RT.c
 
-CGEMM3MKERNEL    =  zgemm3m_kernel_8x4_core2.S
-ZGEMM3MKERNEL    =  zgemm3m_kernel_4x4_core2.S
-
-
-
 

kernel/arm/ddot_vfpv3.S

@@ -0,0 +1,238 @@
+/***************************************************************************
+Copyright (c) 2013, The OpenBLAS Project
+All rights reserved.
+Redistribution and use in source and binary forms, with or without
+modification, are permitted provided that the following conditions are
+met:
+1. Redistributions of source code must retain the above copyright
+notice, this list of conditions and the following disclaimer.
+2. Redistributions in binary form must reproduce the above copyright
+notice, this list of conditions and the following disclaimer in
+the documentation and/or other materials provided with the
+distribution.
+3. Neither the name of the OpenBLAS project nor the names of
+its contributors may be used to endorse or promote products
+derived from this software without specific prior written permission.
+THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
+AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ARE DISCLAIMED. IN NO EVENT SHALL THE OPENBLAS PROJECT OR CONTRIBUTORS BE
+LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
+SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
+OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE
+USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*****************************************************************************/
+
+/**************************************************************************************
+* 2013/11/07 Saar
+* 	 BLASTEST 		: OK
+* 	 CTEST			: OK
+* 	 TEST			: OK
+*
+**************************************************************************************/
+
+#define ASSEMBLER
+#include "common.h"
+
+#define STACKSIZE 256
+
+#define	N	r0
+#define	X	r1
+#define	INC_X	r2
+#define	OLD_Y	r3
+
+
+/******************************************************
+* [fp, #-128] - [fp, #-64] is reserved
+* for store and restore of floating point
+* registers
+*******************************************************/
+
+#define OLD_INC_Y	[fp, #4 ]
+
+#define I	r5
+#define Y	r6
+#define INC_Y	r7
+
+#define X_PRE	256
+
+/**************************************************************************************
+* Macro definitions
+**************************************************************************************/
+
+.macro KERNEL_F4
+
+	pld	[ X, #X_PRE  ]
+	pld	[ Y, #X_PRE  ]
+	fldmiad	X!, { d8 - d9 }
+	fldmiad	Y!, { d4 - d5}
+	fmacd   d0  , d4,  d8
+	fldmiad	X!, { d10 - d11 }
+	fmacd   d1  , d5,  d9
+	fldmiad	Y!, { d6 - d7 }
+	fmacd   d0  , d6,  d10
+	fmacd   d1  , d7,  d11
+
+.endm
+
+.macro KERNEL_F1
+
+	fldmiad	X!, { d4 }
+	fldmiad	Y!, { d8 }
+	fmacd   d0  , d4,  d8
+
+.endm
+
+
+/*************************************************************************************************************************/
+
+.macro KERNEL_S4
+
+	nop
+	fldmiad	X, { d4 }
+	fldmiad	Y, { d8 }
+	add	X, X, INC_X
+	add	Y, Y, INC_Y
+	fmacd   d0  , d4,  d8
+
+	fldmiad	X, { d5 }
+	fldmiad	Y, { d9 }
+	add	X, X, INC_X
+	add	Y, Y, INC_Y
+	fmacd   d1  , d5,  d9
+
+	fldmiad	X, { d6 }
+	fldmiad	Y, { d10 }
+	add	X, X, INC_X
+	add	Y, Y, INC_Y
+	fmacd   d0  , d6,  d10
+
+	fldmiad	X, { d7 }
+	fldmiad	Y, { d11 }
+	add	X, X, INC_X
+	add	Y, Y, INC_Y
+	fmacd   d1  , d7,  d11
+
+.endm
+
+
+.macro KERNEL_S1
+
+	fldmiad	X, { d4 }
+	fldmiad	Y, { d8 }
+	add	X, X, INC_X
+	fmacd   d0  , d4,  d8
+	add	Y, Y, INC_Y
+
+.endm
+
+
+
+/**************************************************************************************
+* End of macro definitions
+**************************************************************************************/
+
+	PROLOGUE
+
+	.align 5
+
+	push	{r4 - r9, fp}
+	add	fp, sp, #24
+	sub	sp, sp, #STACKSIZE				// reserve stack
+
+	sub	r4, fp, #128
+	vstm	r4, { d8 - d15} 				// store floating point registers
+
+	mov	Y, OLD_Y
+	ldr	INC_Y, OLD_INC_Y
+	
+	vsub.f64                d0 , d0 , d0
+	vsub.f64                d1 , d1 , d1
+
+	cmp	N, #0
+	ble	ddot_kernel_L999
+
+	cmp	INC_X, #0
+	beq	ddot_kernel_L999
+
+	cmp	INC_Y, #0
+	beq	ddot_kernel_L999
+
+	cmp	INC_X, #1
+	bne	ddot_kernel_S_BEGIN
+
+	cmp	INC_Y, #1
+	bne	ddot_kernel_S_BEGIN
+
+ddot_kernel_F_BEGIN:
+
+	asrs	I, N, #2					// I = N / 4
+	ble	ddot_kernel_F1
+
+ddot_kernel_F4:
+
+	KERNEL_F4
+
+	subs	I, I, #1
+	bne	ddot_kernel_F4
+
+ddot_kernel_F1:
+
+	ands	I, N, #3
+	ble	ddot_kernel_L999
+
+ddot_kernel_F10:
+
+	KERNEL_F1
+
+	subs    I, I, #1
+        bne     ddot_kernel_F10
+
+	b	ddot_kernel_L999
+
+ddot_kernel_S_BEGIN:
+
+	lsl	INC_X, INC_X, #3				// INC_X * SIZE
+	lsl	INC_Y, INC_Y, #3				// INC_Y * SIZE
+
+	asrs	I, N, #2					// I = N / 4
+	ble	ddot_kernel_S1
+
+ddot_kernel_S4:
+
+	KERNEL_S4
+
+	subs	I, I, #1
+	bne	ddot_kernel_S4
+
+ddot_kernel_S1:
+
+	ands	I, N, #3
+	ble	ddot_kernel_L999
+
+ddot_kernel_S10:
+
+	KERNEL_S1
+
+	subs    I, I, #1
+        bne     ddot_kernel_S10
+
+
+
+
+
+
+ddot_kernel_L999:
+
+	sub	r3, fp, #128
+	vldm	r3, { d8 - d15}					// restore floating point registers
+
+	vadd.f64	d0 , d0, d1				// set return value
+	sub	sp, fp, #24
+	pop	{r4 - r9, fp}
+	bx	lr
+
+	EPILOGUE
+

kernel/arm/sdot_vfpv3.S

@@ -0,0 +1,347 @@
+/***************************************************************************
+Copyright (c) 2013, The OpenBLAS Project
+All rights reserved.
+Redistribution and use in source and binary forms, with or without
+modification, are permitted provided that the following conditions are
+met:
+1. Redistributions of source code must retain the above copyright
+notice, this list of conditions and the following disclaimer.
+2. Redistributions in binary form must reproduce the above copyright
+notice, this list of conditions and the following disclaimer in
+the documentation and/or other materials provided with the
+distribution.
+3. Neither the name of the OpenBLAS project nor the names of
+its contributors may be used to endorse or promote products
+derived from this software without specific prior written permission.
+THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
+AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ARE DISCLAIMED. IN NO EVENT SHALL THE OPENBLAS PROJECT OR CONTRIBUTORS BE
+LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
+SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
+OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE
+USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*****************************************************************************/
+
+/**************************************************************************************
+* 2013/11/07 Saar
+* 	 BLASTEST 		: OK
+* 	 CTEST			: OK (no test for dsdot)
+* 	 TEST			: OK (no test for dsdot)
+*
+**************************************************************************************/
+
+#define ASSEMBLER
+#include "common.h"
+
+#define STACKSIZE 256
+
+#define	N	r0
+#define	X	r1
+#define	INC_X	r2
+#define	OLD_Y	r3
+
+
+/******************************************************
+* [fp, #-128] - [fp, #-64] is reserved
+* for store and restore of floating point
+* registers
+*******************************************************/
+
+#define OLD_INC_Y	[fp, #4 ]
+
+#define I	r5
+#define Y	r6
+#define INC_Y	r7
+
+#define X_PRE	256
+
+/**************************************************************************************
+* Macro definitions
+**************************************************************************************/
+
+#if defined(DSDOT)
+
+.macro KERNEL_F4
+
+	fldmias	X!, { s14 }
+	fldmias	Y!, { s15 }
+	vmul.f32   s15, s14, s15
+	vcvt.f64.f32	d16, s15
+	vadd.f64   d0  , d0,  d16
+
+	fldmias	X!, { s14 }
+	fldmias	Y!, { s15 }
+	vmul.f32   s15, s14, s15
+	vcvt.f64.f32	d16, s15
+	vadd.f64   d0  , d0,  d16
+
+	fldmias	X!, { s14 }
+	fldmias	Y!, { s15 }
+	vmul.f32   s15, s14, s15
+	vcvt.f64.f32	d16, s15
+	vadd.f64   d0  , d0,  d16
+
+	fldmias	X!, { s14 }
+	fldmias	Y!, { s15 }
+	vmul.f32   s15, s14, s15
+	vcvt.f64.f32	d16, s15
+	vadd.f64   d0  , d0,  d16
+
+.endm
+
+.macro KERNEL_F1
+
+	fldmias	X!, { s14 }
+	fldmias	Y!, { s15 }
+	vmul.f32   s15, s14, s15
+	vcvt.f64.f32	d16, s15
+	vadd.f64   d0  , d0,  d16
+
+.endm
+
+
+.macro KERNEL_S4
+
+	nop
+
+	fldmias	X, { s14 }
+	fldmias	Y, { s15 }
+	vmul.f32   s15, s14, s15
+	vcvt.f64.f32	d16, s15
+	vadd.f64   d0  , d0,  d16
+	add	X, X, INC_X
+	add	Y, Y, INC_Y
+
+	fldmias	X, { s14 }
+	fldmias	Y, { s15 }
+	vmul.f32   s15, s14, s15
+	vcvt.f64.f32	d16, s15
+	vadd.f64   d0  , d0,  d16
+	add	X, X, INC_X
+	add	Y, Y, INC_Y
+
+	fldmias	X, { s14 }
+	fldmias	Y, { s15 }
+	vmul.f32   s15, s14, s15
+	vcvt.f64.f32	d16, s15
+	vadd.f64   d0  , d0,  d16
+	add	X, X, INC_X
+	add	Y, Y, INC_Y
+
+	fldmias	X, { s14 }
+	fldmias	Y, { s15 }
+	vmul.f32   s15, s14, s15
+	vcvt.f64.f32	d16, s15
+	vadd.f64   d0  , d0,  d16
+	add	X, X, INC_X
+	add	Y, Y, INC_Y
+
+.endm
+
+
+.macro KERNEL_S1
+
+	fldmias	X, { s14 }
+	fldmias	Y, { s15 }
+	vmul.f32   s15, s14, s15
+	vcvt.f64.f32	d16, s15
+	vadd.f64   d0  , d0,  d16
+	add	X, X, INC_X
+	add	Y, Y, INC_Y
+
+.endm
+
+
+
+#else
+
+.macro KERNEL_F4
+
+	fldmias	X!, { s8 - s9 }
+	fldmias	Y!, { s4 - s5}
+	fmacs   s0  , s4,  s8
+	fldmias	X!, { s10 - s11 }
+	fmacs   s1  , s5,  s9
+	fldmias	Y!, { s6 - s7 }
+	fmacs   s0  , s6,  s10
+	fmacs   s1  , s7,  s11
+
+.endm
+
+.macro KERNEL_F1
+
+	fldmias	X!, { s4 }
+	fldmias	Y!, { s8 }
+	fmacs   s0  , s4,  s8
+
+.endm
+
+
+.macro KERNEL_S4
+
+	nop
+	fldmias	X, { s4 }
+	fldmias	Y, { s8 }
+	add	X, X, INC_X
+	add	Y, Y, INC_Y
+	fmacs   s0  , s4,  s8
+
+	fldmias	X, { s5 }
+	fldmias	Y, { s9 }
+	add	X, X, INC_X
+	add	Y, Y, INC_Y
+	fmacs   s1  , s5,  s9
+
+	fldmias	X, { s6 }
+	fldmias	Y, { s10 }
+	add	X, X, INC_X
+	add	Y, Y, INC_Y
+	fmacs   s0  , s6,  s10
+
+	fldmias	X, { s7 }
+	fldmias	Y, { s11 }
+	add	X, X, INC_X
+	add	Y, Y, INC_Y
+	fmacs   s1  , s7,  s11
+
+.endm
+
+
+.macro KERNEL_S1
+
+	fldmias	X, { s4 }
+	fldmias	Y, { s8 }
+	add	X, X, INC_X
+	fmacs   s0  , s4,  s8
+	add	Y, Y, INC_Y
+
+.endm
+
+#endif
+
+/**************************************************************************************
+* End of macro definitions
+**************************************************************************************/
+
+	PROLOGUE
+
+	.align 5
+
+	push	{r4 - r9, fp}
+	add	fp, sp, #24
+	sub	sp, sp, #STACKSIZE				// reserve stack
+
+	sub	r4, fp, #128
+	vstm	r4, { s8 - s15 } 				// store floating point registers
+
+	mov	Y, OLD_Y
+	ldr	INC_Y, OLD_INC_Y
+	
+#if	defined(DSDOT)
+
+	vsub.f64                d0 , d0 , d0
+	vsub.f64                d1 , d1 , d1
+
+#else
+
+	vsub.f32                s0 , s0 , s0
+	vsub.f32                s1 , s1 , s1
+
+#endif
+
+	cmp	N, #0
+	ble	sdot_kernel_L999
+
+	cmp	INC_X, #0
+	beq	sdot_kernel_L999
+
+	cmp	INC_Y, #0
+	beq	sdot_kernel_L999
+
+	cmp	INC_X, #1
+	bne	sdot_kernel_S_BEGIN
+
+	cmp	INC_Y, #1
+	bne	sdot_kernel_S_BEGIN
+
+sdot_kernel_F_BEGIN:
+
+	asrs	I, N, #2					// I = N / 4
+	ble	sdot_kernel_F1
+
+sdot_kernel_F4:
+
+	KERNEL_F4
+
+	subs	I, I, #1
+	bne	sdot_kernel_F4
+
+sdot_kernel_F1:
+
+	ands	I, N, #3
+	ble	sdot_kernel_L999
+
+sdot_kernel_F10:
+
+	KERNEL_F1
+
+	subs    I, I, #1
+        bne     sdot_kernel_F10
+
+	b	sdot_kernel_L999
+
+sdot_kernel_S_BEGIN:
+
+	lsl	INC_X, INC_X, #2				// INC_X * SIZE
+	lsl	INC_Y, INC_Y, #2				// INC_Y * SIZE
+
+	asrs	I, N, #2					// I = N / 4
+	ble	sdot_kernel_S1
+
+sdot_kernel_S4:
+
+	KERNEL_S4
+
+	subs	I, I, #1
+	bne	sdot_kernel_S4
+
+sdot_kernel_S1:
+
+	ands	I, N, #3
+	ble	sdot_kernel_L999
+
+sdot_kernel_S10:
+
+	KERNEL_S1
+
+	subs    I, I, #1
+        bne     sdot_kernel_S10
+
+
+
+
+
+
+sdot_kernel_L999:
+
+	sub	r3, fp, #128
+	vldm	r3, { s8 - s15}					// restore floating point registers
+
+#if	defined(DSDOT)
+
+	vadd.f64	d0 , d0, d1				// set return value
+
+#else
+
+	vadd.f32	s0 , s0, s1				// set return value
+
+#endif
+	sub	sp, fp, #24
+	pop	{r4 - r9, fp}
+	bx	lr
+
+	EPILOGUE
+